Answer set programming (ASP) is a form of declarative programming oriented towards difficult (primarily NP-hard) search problems. It is based on the stable model (answer set) semantics of logic programming. In ASP, search problems are reduced to computing stable models, and answer set solvers — programs for generating stable models—are used to perform search. The computational process employed in the design of many answer set solvers is an enhancement of the DPLL algorithm and, in principle, it always terminates (unlike Prolog query evaluation, which may lead to an infinite loop).

In a more general sense, ASP includes all applications of answer sets to knowledge representation[1][2] and the use of Prolog-style query evaluation for solving problems arising in these applications.

## History

The planning method proposed in 1993 by Dimopoulos, Nebel and Köhler[3] is an early example of answer set programming. Their approach is based on the relationship between plans and stable models.[4] Soininen and Niemelä[5] applied what is now known as answer set programming to the problem of product configuration. The use of answer set solvers for search was identified as a new programming paradigm by Marek and Truszczyński in a paper that appeared in a 25-year perspective on the logic programming paradigm published in 1999 [6] and in [Niemelä 1999].[7] Indeed, the new terminology of "answer set" instead of "stable model" was first proposed by Lifschitz[8] in a paper appearing in the same retrospective volume as the Marek-Truszczynski paper.

## Answer set programming language AnsProlog

Lparse is the name of the program that was originally created as grounding tool (front-end) for the answer set solver smodels. The language that Lparse accepts is now commonly called AnsProlog*,[9] short for Answer Set Programming in Logic.[10] It is now used in the same way in many other answer set solvers, including assat, clasp, cmodels, gNt, nomore++ and pbmodels. (dlv is an exception; the syntax of ASP programs written for dlv is somewhat different.)

An AnsProlog program consists of rules of the form

```<head> :- <body> .
```

The symbol `:-` ("if") is dropped if `<body>` is empty; such rules are called facts. The simplest kind of Lparse rules are rules with constraints.

One other useful construct included in this language is choice. For instance, the choice rule

```{p,q,r}.
```

says: choose arbitrarily which of the atoms ${\displaystyle p,q,r}$ to include in the stable model. The lparse program that contains this choice rule and no other rules has 8 stable models—arbitrary subsets of ${\displaystyle \{p,q,r\}}$. The definition of a stable model was generalized to programs with choice rules.[11] Choice rules can be treated also as abbreviations for propositional formulas under the stable model semantics.[12] For instance, the choice rule above can be viewed as shorthand for the conjunction of three "excluded middle" formulas:

${\displaystyle (p\lor \neg p)\land (q\lor \neg q)\land (r\lor \neg r).}$

The language of lparse allows us also to write "constrained" choice rules, such as

```1{p,q,r}2.
```

This rule says: choose at least 1 of the atoms ${\displaystyle p,q,r}$, but not more than 2. The meaning of this rule under the stable model semantics is represented by the propositional formula

${\displaystyle (p\lor \neg p)\land (q\lor \neg q)\land (r\lor \neg r)}$
${\displaystyle \land \,(p\lor q\lor r)\land \neg (p\land q\land r).}$

Cardinality bounds can be used in the body of a rule as well, for instance:

```:- 2{p,q,r}.
```

Adding this constraint to an Lparse program eliminates the stable models that contain at least 2 of the atoms ${\displaystyle p,q,r}$. The meaning of this rule can be represented by the propositional formula

${\displaystyle \neg ((p\land q)\lor (p\land r)\lor (q\land r)).}$

Variables (capitalized, as in Prolog) are used in Lparse to abbreviate collections of rules that follow the same pattern, and also to abbreviate collections of atoms within the same rule. For instance, the Lparse program

```p(a). p(b). p(c).
q(X) :- p(X), X!=a.
```

has the same meaning as

```p(a). p(b). p(c).
q(b). q(c).
```

The program

```p(a). p(b). p(c).
{q(X):-p(X)}2.
```

is shorthand for

```p(a). p(b). p(c).
{q(a),q(b),q(c)}2.
```

A range is of the form:

```<Predicate>(start..end)
```

where start and end are constant valued arithmetic expressions. A range is a notational shortcut that is mainly used to define numerical domains in a compatible way. For example, the fact

```a(1..3).
```

is a shortcut for

```a(1). a(2). a(3).
```

Ranges can also be used in rule bodies with the same semantics.

A conditional literal is of the form:

```p(X):q(X)
```

If the extension of q is {q(a1); q(a2); ... ; q(aN)}, the above condition is semantically equivalent to writing p(a1), p(a2), ... , p(aN) in the place of the condition. For example

```q(1..2).
a :- 1 {p(X):q(X)}.
```

is a shorthand for

```q(1). q(2).
a :- 1 {p(1), p(2)}.
```

## Generating stable models

To find a stable model of the Lparse program stored in file `<filename>` we use the command

```% lparse <filename> | smodels
```

Option 0 instructs smodels to find all stable models of the program. For instance, if file `test` contains the rules

```1{p,q,r}2.
s :- not p.
```

then the command

```% lparse test | smodels 0
```

produces the output

```Answer: 1
Stable Model: q p
Stable Model: p
Stable Model: r p
Stable Model: q s
Stable Model: r s
Stable Model: r q s
```

## Examples of ASP programs

### Graph coloring

An ${\displaystyle n}$-coloring of a graph ${\displaystyle G}$ is a function ${\displaystyle color\ }$ from its set of vertices to ${\displaystyle \{1,\dots ,n\}}$ such that ${\displaystyle color(x)\neq color(y)}$ for every pair of adjacent vertices ${\displaystyle x,y}$. We would like to use ASP to find an ${\displaystyle n}$-coloring of a given graph (or determine that it does not exist).

This can be accomplished using the following Lparse program:

```c(1..n).
1 {color(X,I) : c(I)} 1 :- v(X).
:- color(X,I), color(Y,I), e(X,Y), c(I).
```

Line 1 defines the numbers ${\displaystyle 1,\dots ,n}$ to be colors. According to the choice rule in Line 2, a unique color ${\displaystyle i}$ should be assigned to each vertex ${\displaystyle x}$. The constraint in Line 3 prohibits assigning the same color to vertices ${\displaystyle x}$ and ${\displaystyle y}$ if there is an edge connecting them.

If we combine this file with a definition of ${\displaystyle G}$, such as

```v(1..100). % 1,...,100 are vertices
e(1,55). % there is an edge from 1 to 55
. . .
```

and run smodels on it, with the numeric value of ${\displaystyle n}$ specified on the command line, then the atoms of the form ${\displaystyle color(\dots ,\dots )}$ in the output of smodels will represent an ${\displaystyle n}$-coloring of ${\displaystyle G}$.

The program in this example illustrates the "generate-and-test" organization that is often found in simple ASP programs. The choice rule describes a set of "potential solutions" — a simple superset of the set of solutions to the given search problem. It is followed by a constraint, which eliminates all potential solutions that are not acceptable. However, the search process employed by smodels and other answer set solvers is not based on trial and error.

### Large clique

A clique in a graph is a set of pairwise adjacent vertices. The following lparse program finds a clique of size ${\displaystyle \geq n}$ in a given graph, or determines that it does not exist:

```n {in(X) : v(X)}.
:- in(X), in(Y), v(X), v(Y), X!=Y, not e(X,Y), not e(Y,X).
```

This is another example of the generate-and-test organization. The choice rule in Line 1 "generates" all sets consisting of ${\displaystyle \geq n}$ vertices. The constraint in Line 2 "weeds out" the sets that are not cliques.

### Hamiltonian cycle

A Hamiltonian cycle in a directed graph is a cycle that passes through each vertex of the graph exactly once. The following Lparse program can be used to find a Hamiltonian cycle in a given directed graph if it exists; we assume that 0 is one of the vertices.

```{in(X,Y)} :- e(X,Y).

:- 2 {in(X,Y) : e(X,Y)}, v(X).
:- 2 {in(X,Y) : e(X,Y)}, v(Y).

r(X) :- in(0,X), v(X).
r(Y) :- r(X), in(X,Y), e(X,Y).

:- not r(X), v(X).
```

The choice rule in Line 1 "generates" all subsets of the set of edges. The three constraints "weed out" the subsets that are not Hamiltonian cycles. The last of them uses the auxiliary predicate ${\displaystyle r(x)}$ ("${\displaystyle x}$ is reachable from 0") to prohibit the vertices that do not satisfy this condition. This predicate is defined recursively in Lines 4 and 5.

This program is an example of the more general "generate, define and test" organization: it includes the definition of an auxiliary predicate that helps us eliminate all "bad" potential solutions.

## Comparison of implementations

Early systems, such as Smodels, used backtracking to find solutions. As the theory and practice of Boolean SAT solvers evolved, a number of ASP solvers were built on top of SAT solvers, including ASSAT and Cmodels. These converted ASP formula into SAT propositions, applied the SAT solver, and then converted the solutions back to ASP form. More recent systems, such as Clasp, use a hybrid approach, using conflict-driven algorithms inspired by SAT, without full converting into a boolean-logic form. These approaches allow for significant improvements of performance, often by an order of magnitude, over earlier backtracking algorithms.

The Potassco project acts as an umbrella for many of the systems below, including clasp, grounding systems (gringo), incremental systems (iclingo), constraint solvers (clingcon), action language to ASP compilers (coala), distributed MPI implementations (claspar), and many others.

Most systems support variables, but only indirectly, by forcing grounding, by using a grounding system such as Lparse or gringo as a front end. The need for grounding can cause a combinatorial explosion of clauses; thus, systems that perform on-the-fly grounding might have an advantage.

Platform Features Mechanics
Name OS Licence Variables Function symbols Explicit sets Explicit lists Disjunctive (choice rules) support
Template:Rh|ASPeRiX Linux GPL Yes No on-the-fly grounding
Template:Rh|ASSAT Solaris Freeware SAT-solver based
Template:Rh|Clasp Answer Set Solver Linux, Mac OS, Windows GPL Yes, in Clingo Yes No No Yes incremental, SAT-solver inspired (nogood, conflict-driven)
Template:Rh|Cmodels Linux, Solaris GPL Template:Okay Yes incremental, SAT-solver inspired (nogood, conflict-driven)
Template:Rh|DLV Linux, Mac OS, Windows[13] free for academic and non-commercial educational use, and for non-profit organizations[13] Yes Yes No No Yes not Lparse compatible
Template:Rh|DLV-Complex Linux, Mac OS, Windows Freeware Yes Yes Yes Yes built on top of DLV — not Lparse compatible
Template:Rh|GnT Linux GPL Template:Okay Yes built on top of smodels
Template:Rh|nomore++ Linux GPL combined literal+rule-based
Template:Rh|Platypus Linux, Solaris, Windows GPL distributed, multi-threaded nomore++, smodels
Template:Rh|Pbmodels Linux ? pseudo-boolean solver based
Template:Rh|Smodels Linux, Mac OS, Windows GPL Template:Okay No No No No
Template:Rh|Smodels-cc Linux ? Template:Okay SAT-solver based; smodels w/conflict clauses
Template:Rh|Sup Linux ? SAT-solver based

## References

1. {{#invoke:citation/CS1|citation |CitationClass=book }}
2. {{#invoke:citation/CS1|citation |CitationClass=book }} as PDF
3. {{#invoke:citation/CS1|citation |CitationClass=book }} as Postscript
4. {{#invoke:citation/CS1|citation |CitationClass=book }} as Postscript
5. {{#invoke:citation/CS1|citation |CitationClass=citation }}
6. {{#invoke:citation/CS1|citation |CitationClass=book }}
7. {{#invoke:Citation/CS1|citation |CitationClass=journal }}
8. Template:Cite thesis
9. Template:Cite web
10. {{#invoke:citation/CS1|citation |CitationClass=book }} as Postscript
11. {{#invoke:Citation/CS1|citation |CitationClass=journal }} as Postscript
12. Template:Cite web